workflow-runner/flake.nix at master · PipeletCloud/workflow-runner · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs";
    flake-parts.url = "github:hercules-ci/flake-parts";
    systems.url = "github:nix-systems/default";
    treefmt-nix.url = "github:numtide/treefmt-nix";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-parts,
      systems,
      treefmt-nix,
      ...
    }@inputs:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = import inputs.systems;
      perSystem =
        { lib, pkgs, ... }:
        let
          treefmtEval = inputs.treefmt-nix.lib.evalModule pkgs {
            projectRootFile = ".git/config";

            programs = {
              nixfmt.enable = true;
              zig.enable = true;
              yamlfmt = {
                enable = true;
                settings.formatter.retain_line_breaks = true;
              };
            };
          };
        in
        {
          formatter = treefmtEval.config.build.wrapper;
          checks.formatting = treefmtEval.config.build.check self;

          packages.default = pkgs.callPackage (
            {
              stdenv,
              zig,
            }:
            stdenv.mkDerivation (finalAttrs: {
              pname = "pipelet-workflow-runner";
              version = "0.1.0-git+${self.shortRev or "dirty"}";

              src = lib.cleanSource ./.;

              nativeBuildInputs = [
                zig
                zig.hook
              ];

              zigDeps = zig.fetchDeps {
                inherit (finalAttrs)
                  src
                  pname
                  version
                  ;
                hash = "sha256-z3h4bvYX40nVRgzU3jZ2Vw92Y87eDXqdEvNgLJwPM1s=";
              };

              postUnpack = ''
                ln -s ${finalAttrs.zigDeps} $ZIG_GLOBAL_CACHE_DIR/p
              '';

              meta = {
                description = "Workflow runner for pipelet.io";
                licenses = with lib.licenses; [ lgpl21Only ];
                maintainers = with lib.maintainers; [ RossComputerGuy ];
                homepage = "https://pipelet.io";
              };
            })
          ) { };
        };
    };
}