grpc-java-jwt/build.gradle at main · avast/grpc-java-jwt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
plugins {
    id 'com.google.protobuf' version '0.9.6' apply false
    id 'com.avast.gradle.docker-compose' version '0.17.21' apply false
    id 'org.jreleaser' version '1.22.0'
}

allprojects {
    group 'com.avast.grpc.jwt'
    version = version == 'unspecified' ? 'DEVELOPER-SNAPSHOT' : version
}

ext {
    grpcVersion = '1.80.0'
    protobufVersion = '3.25.9'
}

tasks.register('clean') {}

subprojects {
    apply plugin: 'java'
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'
    apply plugin: 'org.jreleaser'

    repositories {
        mavenCentral()
    }

    dependencies {
        testImplementation 'junit:junit:4.13.2'
        testImplementation 'org.mockito:mockito-core:5.22.0'
    }

    test {
        testLogging {
            events 'failed'
            exceptionFormat 'full'
        }
    }


    java {
        withJavadocJar()
        withSourcesJar()
    }

    afterEvaluate {
        publishing {
            publications {
                mavenJava(MavenPublication) {
                    from(components.java)
                    artifactId = tasks.jar.archiveBaseName.get()
                    pom {
                        name = 'gRPC Java JWT'
                        description = 'JWT based authentication for gRPC-Java'
                        url = 'https://github.com/avast/grpc-java-jwt'
                        licenses {
                            license {
                                name = 'The MIT License'
                                url = 'http://www.opensource.org/licenses/mit-license.php'
                            }
                        }
                        developers {
                            developer {
                                id = 'augi'
                                name = 'Michal Augustýn'
                                email = 'augustyn.michal@gmail.com'
                            }
                        }
                        scm {
                            connection = 'scm:git:git://github.com/avast/grpc-java-jwt.git'
                            developerConnection = 'scm:git:ssh://github.com/avast/grpc-java-jwt.git'
                            url = 'https://github.com/avast/grpc-java-jwt'
                        }
                    }
                }
            }
            repositories {
                maven {
                    url = layout.buildDirectory.dir('staging-deploy')
                }
            }
        }
    }

    jreleaser {
        signing {
            active = 'ALWAYS'
            armored = true
            String base64Key = System.getenv('SIGNING_KEY')
            if (base64Key) {
                secretKey = new String(Base64.decoder.decode(base64Key))
            }
            String base64PublicKey = System.getenv('SIGNING_PUBLIC_KEY')
            if (base64PublicKey) {
                publicKey = new String(Base64.decoder.decode(base64PublicKey))
            }
        }
        deploy {
            maven {
                mavenCentral {
                    sonatype {
                        active = 'ALWAYS'
                        url = 'https://central.sonatype.com/api/v1/publisher'
                        stagingRepository('build/staging-deploy')
                    }
                }
            }
        }
        release {
            github {
                enabled = false
            }
        }
    }
}