WordPress-Android/build.gradle at trunk · wordpress-mobile/WordPress-Android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
import com.automattic.android.measure.reporters.InternalA8cCiReporter
import com.automattic.android.measure.reporters.RemoteBuildCacheMetricsReporter
import com.automattic.android.measure.reporters.SlowSlowTasksMetricsReporter
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    alias(libs.plugins.detekt)
    alias(libs.plugins.automattic.measure.builds)
    alias(libs.plugins.kotlinx.kover)
    alias(libs.plugins.dependency.analysis)
    alias(libs.plugins.androidx.navigation.safeargs).apply(false)
    alias(libs.plugins.android.application).apply(false)
    alias(libs.plugins.android.library).apply(false)
    alias(libs.plugins.google.services).apply(false)
    alias(libs.plugins.kotlin.allopen).apply(false)
    alias(libs.plugins.kotlin.compose).apply(false)
    alias(libs.plugins.kotlin.jvm).apply(false)
    alias(libs.plugins.kotlin.parcelize).apply(false)
    alias(libs.plugins.kotlin.serialization).apply(false)
    alias(libs.plugins.ksp).apply(false)
    alias(libs.plugins.legacy.kapt).apply(false)
    alias(libs.plugins.room).apply(false)
}

ext {
    minSdkVersion = 26
    compileSdkVersion = 36
    targetSdkVersion = 36
}

static def loadPropertiesFromFile(File inputFile) {
    def properties = new Properties()
    inputFile.withInputStream { stream ->
        properties.load(stream)
    }
    return properties
}

measureBuilds {
    enable = gradle.ext.secretProperties.get('measureBuildsEnabled')?.toBoolean() ?: false
    onBuildMetricsReadyListener { report ->
        SlowSlowTasksMetricsReporter.report(report)
        RemoteBuildCacheMetricsReporter.report(report)
        InternalA8cCiReporter.reportBlocking(
                report,
                "wordpress",
                gradle.ext.secretProperties.get('appsMetricsToken')
        )
    }
    attachGradleScanId = gradle.ext.isCi
}

allprojects {
    apply plugin: libs.plugins.checkstyle.get().pluginId
    apply plugin: libs.plugins.detekt.get().pluginId

    tasks.register("checkstyle", Checkstyle) {
        source 'src'

        classpath = files()
    }

    checkstyle {
        toolVersion = libs.plugins.checkstyle.get().version
        configFile file("${project.rootDir}/config/checkstyle.xml")
    }

    detekt {
        toolVersion = libs.plugins.detekt.get().version
        baseline = file("${project.rootDir}/config/detekt/baseline.xml")
        config = files("${project.rootDir}/config/detekt/detekt.yml")
        autoCorrect = false
        buildUponDefaultConfig = true
        disableDefaultRuleSets = false
        ignoreFailures = false
        parallel = true
        debug = false
    }

    tasks.withType(KotlinCompile).configureEach {
        compilerOptions {
            jvmTarget = JvmTarget.fromTarget(libs.versions.java.get())
            allWarningsAsErrors = true
            freeCompilerArgs.addAll(
                    "-opt-in=kotlin.RequiresOptIn",
                    "-jvm-default=no-compatibility",
                    "-Xannotation-default-target=param-property",
                    // Suppress Glide KSP codegen visibility warning (bumptech/glide#5601)
                    "-Xwarning-level=" +
                        "EXPOSED_PACKAGE_PRIVATE_TYPE_FROM_INTERNAL_WARNING:disabled"
            )
        }
    }
}

subprojects {
    plugins.withType(com.android.build.gradle.AppPlugin) {
        android {
            lint {
                warningsAsErrors = true
                checkDependencies true
                checkGeneratedSources = true
                lintConfig file("${project.rootDir}/config/lint/lint.xml")
                baseline file("${project.rootDir}/config/lint/baseline.xml")
                sarifReport = gradle.ext.isCi
            }
        }
        dependencies {
            lintChecks(libs.android.security.lint)
            lintChecks(libs.wordpress.lint)
        }
    }
    plugins.withType(com.android.build.gradle.LibraryPlugin) {
        android {
            lint {
                checkDependencies false
                lintConfig file("${project.rootDir}/config/lint/lint.xml")
            }
        }
        dependencies {
            lintChecks(libs.android.security.lint)
            lintChecks(libs.wordpress.lint)
        }
    }
}

dependencies {
    detektPlugins(libs.detekt.formatting)
}

apply from: './config/gradle/code_coverage.gradle'